mirror of
https://github.com/yuezk/GlobalProtect-openconnect.git
synced 2026-11-19 06:26:14 -05:00
51 lines
1.4 KiB
Bash
51 lines
1.4 KiB
Bash
# Maintainer: Kevin Yue <[email protected]>
|
|
|
|
_pkgname_prefix=globalprotect-openconnect
|
|
pkgname="${_pkgname_prefix}-git"
|
|
pkgver=2.5.1.r1.g24f9bbb
|
|
pkgrel=2
|
|
pkgdesc="A GUI client for GlobalProtect VPN, based on OpenConnect, supports the SSO authentication method."
|
|
arch=(x86_64 aarch64)
|
|
url="https://github.com/yuezk/GlobalProtect-openconnect"
|
|
license=('GPL3')
|
|
|
|
makedepends=(git pkg-config make autoconf automake gettext libtool patch curl wget file appmenu-gtk-module librsvg cargo)
|
|
depends=(webkit2gtk-4.1 libappindicator-gtk3 libsecret libxml2 zlib lz4 gnutls libp11-kit nettle libhogweed.so gmp shared-mime-info desktop-file-utils xdg-utils)
|
|
optdepends=('wmctrl: for window management')
|
|
|
|
conflicts=('globalprotect-openconnect')
|
|
provides=('globalprotect-openconnect' 'gpclient' 'gpservice' 'gpauth' 'gpgui')
|
|
|
|
install=gp.install
|
|
|
|
source=("${_pkgname_prefix}::git+https://github.com/yuezk/GlobalProtect-openconnect.git#branch=main")
|
|
|
|
sha256sums=("SKIP")
|
|
|
|
# GCC LTO objects from native dependencies cannot be linked by Rust's LLD.
|
|
options=('!strip' '!lto')
|
|
|
|
pkgver() {
|
|
cd "${_pkgname_prefix}"
|
|
|
|
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
|
|
}
|
|
|
|
prepare() {
|
|
cd "${_pkgname_prefix}"
|
|
git submodule update --init --recursive
|
|
|
|
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
|
|
}
|
|
|
|
build() {
|
|
cd "${_pkgname_prefix}"
|
|
cargo build --frozen --release
|
|
}
|
|
|
|
package() {
|
|
cd "${_pkgname_prefix}"
|
|
|
|
DESTDIR="$pkgdir" make install
|
|
}
|